home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 220
/
220.d81
/
ez f keys v3.bas
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
3KB
|
60 lines
5 dv=peek(186):if dv<8 then dv=8
10 rem version 3 (2003) by james t. jones of modification of program
20 rem 'easy keys' (on issue 46 of loadstar) by steve goldsmith
30 cd$=chr$(17):rem cursor down
40 q$=chr$(34):rem quotation mark
50 cr$=chr$(13):rem carriage return
60 f$(1)="[147] close15:open15,dv,15,"+q$+"v0"+q$+":close15"+cr$:rem validate disk
70 f$(2)="[147] sys 267"+cr$:rem displays variables of disk drive error channel
80 f$(3)="[147] sys52736"+cr$:rem displays directory; analogous to f3 key on c-128
90 f$(4)="[147] "+chr$(147)+cr$:rem clears screen; analogous to f4 key on c-128
100 f$(5)="[147] print chr$(14)"+cr$:rem changes case to lower case
110 f$(6)="[147] run"+cr$:rem analogous to initial assignment of f6 key on c-128
120 f$(7)="[147] list"+cr$:rem analogous to initial assignment of f7 key on c-128
130 f$(8)="[147] close15:open15,dv,15,"+q$+"i0"+q$+":close15"+cr$:rem initialize
132 rem disk drive
140 poke53280,0:poke53281,0:print"[147]"chr$(14):poke214,11:print
150 printspc(15)"[204][207][193][196][201][206][199] files...."
160 sys57812"ez f keys.o",dv,0:poke780,0:poke781,16:poke782,192:sys65493
170 sys57812"univdir(52736).o",dv,0:poke780,0:poke781,0:poke782,206:sys65493
180 sys57812"drive chk(267).o",dv,0:poke780,0:poke781,11:poke782,1:sys65493
190 t$="[197][218] [198]-[203][197][217][211] [214]3":print"[147]"spc(20-len(t$)/2)t$""
200 print" [212]his program creates operations"
210 print"accessed by pressing the indicated"
220 print"function keys. [215]ith some exceptions,"
222 print"they are analogous to the initial [198]"
224 print"key assignments of the [195]-128."
230 print"[198]1: validate disk (unlike [195]-128)"
240 print"[198]2: enter sys 267: displays disk"
260 print" drive status (unlike [195]-128)"
270 print"[198]3: enter sys 52736: displays directory"
280 print" (like [195]-128)"
300 print"[198]4: clears screen (like [195]-128)"
320 print" press <[211][208][193][195][197]> to continue"
330 geta$:if a$<>" " then330
340 print"[147][198]5: changes case to lower case"
350 print"[198]6: run (like [195]-128)"
360 print"[198]7: list (like [195]-128)"
370 print"[198]8: initialize disk drive (unlike 128)"
380 print" [194]y changing the expressions for"
390 print"the functions f$(n) in the beginning"
400 print"lines of the program, you can modify"
410 print"the operations that the function keys"
420 print"carry out. [217]ou will want to change"
430 print"the corresponding descriptions, as"
440 print"well. [194]e sure to [211][193][214][197] the resulting"
450 print"program!"
460 print" [206]ow, exit the program and use"
470 print"those function keys on your [195]-64!"
480 poke214,20:print:print" press <[211][208][193][195][197]> to exit program"
490 geta$:if a$<>" " then490
500 bu=49408:open1,0
510 print"[147] [201]nformation is being entered.... [146]"
520 fora=1to8:hi=int(bu/256):lo=bu-hi*256:poke49152+(a-1)*2,lo
530 poke49153+(a-1)*2,hi:readb:forc=1tolen(f$(b))
540 poke bu,asc(mid$(f$(b),c,1)+chr$(0)):bu=bu+1:next:next:close1,0:sys49168:end
560 rem function key evaluation
570 data7,1,3,5,8,2,4,6
10000 n$="ez f keys v3.bas":d=peek(186):if d<8 then d=8
10010 close15:open15,d,15,"s:"+n$:close15:save n$,d:verify n$,d:end